【DOS】16位汇编实现DOS下256色图形文本模式旋转的菱形的表示

0xAA55

下面的源码只是图形模式的。文本模式的源码请看附件。

1. %define SCRWIDTH        320                        ;屏幕横向分辨率
   
2. %define SCRHEIGHT        200                        ;屏幕纵向分辨率
   
3. %define DIAMONDSIZE        50                        ;菱形的“半径”
   
4. %define TURNSPEED        0.001                ;每帧转动弧度，必须为浮点数
   
5. 
   
6. start:
   
7. mov ax,0x13                                ;功能0，模式0x13：图形模式，256色，320x200分辨率
   
8. int 0x10                                ;进入图形模式
   
9. 
   
10. xor ax,ax                                ;改写中断向量表
    
11. mov ds,ax
    
12. cli
    
13. mov word[0x1C*4],TimerINT        ;新的时钟中断
    
14. mov [0x1C*4+2],cs
    
15. sti
    
16. mov ax,cs
    
17. mov ds,ax
    
18. 
    
19. mov ax,0xA000                        ;显存
    
20. mov es,ax
    
21. 
    
22. finit                                        ;初始化FPU
    
23. Show:                                        ;开始单帧渲染
    
24. ;hlt                                        ;等待一次中断。hlt会引起DOSBOX异常
    
25. fwait
    
26. 
    
27. ;取得时间
    
28. mov al,0x06                                ;中断计时器值以便于读取
    
29. out 0x43,al
    
30. in al,0x40                                ;读取计时器低位
    
31. mov ah,al
    
32. in al,0x40                                ;读取计时器高位
    
33. xchg ah,al                                ;交换高低位
    
34. not ax                                        ;得到计时器时钟数
    
35. mov [Time.Low],ax
    
36. fild qword[Time]                ;读时钟计数
    
37. fcom qword[Time.Old]        ;比较旧的时间值
    
38. fstsw ax
    
39. fwait
    
40. sahf
    
41. ja .TimeOK                                ;当新取得的时钟计数比旧的低时，更正时钟计数
    
42. inc dword[cs:Time.High]
    
43. fst st0
    
44. fild qword[Time]                ;重新加载正确的时间
    
45. fwait
    
46. .TimeOK:
    
47. fst qword[Time.Old]                ;将已经算出的时间存储起来，用于下一轮比较
    
48. fmul qword[C_SPEED]                ;转动速度
    
49. fdiv qword[CrystalFreq]        ;晶振频率
    
50. ;得到角度
    
51. 
    
52. fld st0                                        ;复制“角度”
    
53. fcos                                        ;求“角度”余弦
    
54. fst qword[Matrix.X_X]        ;一个存到矩阵的X_X
    
55. fstp qword[Matrix.Y_Y]        ;一个存到矩阵的Y_Y
    
56. fsin                                        ;求“角度”正弦
    
57. fst qword[Matrix.X_Y]        ;存到矩阵的X_Y
    
58. fchs                                        ;求反
    
59. fstp qword[Matrix.Y_X]        ;存到矩阵的Y_X
    
60. 
    
61. fild dword[C_HALFSCRHEIGHT]
    
62. fchs                                        ;Y
    
63. mov cx,SCRHEIGHT
    
64. xor di,di
    
65. .VLoop:
    
66.         fwait                                ;等FPU处理好
    
67.         fld1
    
68.         fadd                                ;Y+=1.0;
    
69.         fild dword[C_HALFSCRWIDTH]
    
70.         fchs                                ;X
    
71.         push cx
    
72.         mov cx,SCRWIDTH
    
73.         .HLoop:
    
74.                 fld1
    
75.                 fadd                        ;X+=1.0;
    
76.                 fld st1
    
77.                 fmul qword[Matrix.X_Y]
    
78.                 fld st1
    
79.                 fmul qword[Matrix.X_X]
    
80.                 fadd
    
81.                 fabs                        ;NewX=(X*m11+Y*m12)
    
82.                 fistp dword[NewX]
    
83.                
    
84.                 fld st1
    
85.                 fmul qword[Matrix.Y_Y]
    
86.                 fld st1
    
87.                 fmul qword[Matrix.Y_X]
    
88.                 fadd
    
89.                 fabs                        ;NewY=(X*m21+Y*m22)
    
90.                 fistp dword[NewY]
    
91. 
    
92.                 fwait                        ;等FPU处理好
    
93. 
    
94.                 xor al,al
    
95.                 cmp dword[NewX],DIAMONDSIZE
    
96.                 ja .OutOfStupidDiamond
    
97.                 cmp dword[NewY],DIAMONDSIZE
    
98.                 ja .OutOfStupidDiamond
    
99.                 mov al,[NewX]
    
100.                 add al,[NewY]        ;AL为颜色值，设置AL为调色板颜色
     
101.                 .OutOfStupidDiamond:
     
102.                 stosb                        ;输出一个像素
     
103.         loop .HLoop
     
104.         pop cx
     
105.         fstp st0                        ;保护浮点堆栈
     
106. loop .VLoop
     
107. fstp st0                                ;保护浮点堆栈
     
108. jmp Show
     
109. 
     
110. NewX dd 0
     
111. NewY dd 0
     
112. C_HALFSCRWIDTH dd SCRWIDTH/2
     
113. C_HALFSCRHEIGHT dd SCRHEIGHT/2
     
114. C_SPEED dq TURNSPEED
     
115. 
     
116. Matrix:                ;旋转变换矩阵
     
117. .X_X dq 1.0        ;矩阵X轴
     
118. .X_Y dq 0.0
     
119. .Y_X dq 0.0        ;矩阵Y轴
     
120. .Y_Y dq 1.0
     
121. 
     
122. Time:
     
123. .Low dw 0        ;时间
     
124. .High dd 0        ;时钟中断计数
     
125. .Top dw 0        ;8字节对齐
     
126. .Old dq 0        ;旧的时间
     
127. 
     
128. CrystalFreq dq 1193.182
     
129. 
     
130. TimerINT:
     
131. inc dword[cs:Time.High]
     
132. iret

复制代码

完整源码和编译器，回复后可见。

游客，如果您要查看本帖隐藏内容请回复

我有个梦

lz好厉害

0xAA55

已更新，提升了计时器精度。

大家可以从源码中看到我是怎么做浮点数比较的。
其实浮点数比较有很多种方法。
1、fcom之后，用fstsw将状态字写入ax，然后用sahf将ah的值写入eflags，之后就可以用jcc等条件判断指令了。
2、直接用fcomi，然后jcc等条件判断指令。
3、用两个待比较的浮点数做减法，然后将结果用fst存入内存，再判断这个存储的值的最高位是否为1——是的话第一个数比第二个数小。一定不要忘了fwait，否则FPU还没来得及写入数字，你就从内存取值了。

langzhe

666666666666

bigwind

16位汇编实现DOS下256色图形文本模式旋转的菱形的表示

137734949

     

夜凌夕殇

厉害                              

watermelon

哇好厉害，还是有好多指令不认识，好在有注释

FFFFFFFE

这个真的厉害了.

村中一霸

真是厉害，膜拜了，新手学习